処理概要：取引先の部門項目を一括で更新するApexバッチ処理となります。

以下、取引先部門が未設定の取引先レコードに対して、一括で’未設定’という固定値を設定する処理

バッチを実行することで、以下のように取引先部門に’未設定’の文言が一括でセットされます。

Batch Apexのサンプルコード

Batch Apexのサンプルクラス、スケジューラ、テストクラスの基本セット

詳細な仕様は公式の開発者ガイドを参照「Apexの一括処理」してください。

取引先の部門更新処理バッチ（BatchApexUpdateAccount.cls）

/**
 * プログラム名：BatchApexUpdateAccount
 * 概　　　要　：取引先の部門を一括で更新するためのバッチ処理
 * 作　成　日　：2022/07.01
 * 作　成　者　：cclt(David)
 * 変更履歴　　：
 */
global class BatchApexUpdateAccount implements Database.Batchable<sObject>, Database.Stateful {

    //取引先部門に設定する固定値を定義
    private final String SITE_DEFAULT_VALUE = '未指定';

    /**
     * スタートメソッドでは、QueryLocatorを使ってバッチ処理を行うレコードを取得する
     * 本サンプルでは、取引先の部門を更新するため部門がNULLのレコードを全て取得する
     **/
    global Database.QueryLocator start(Database.BatchableContext BC) {
        
        //取引先部門（Site）が未設定の取引先レコードをすべて取得
        String query = 'SELECT Id, Name, Site FROM Account Where Site = null';
        return Database.getQueryLocator(query);
    }
        
    /**
     * スタートで取得したレコードのリストをパラメータとして、メイン処理を実行
     * バッチ実行時に処理するレコード数が指定されていない場合、デフォルトでは200レコードずつ分割して処理される。
     */
    global void execute(Database.BatchableContext BC, List<Account> accList) {
        
        //取得した取引先部門が未指定のレコードについて、固定値'未指定'をセットする。
        for(Account acc : accList) {        
            try {
                //取引先部門に固定値をセット
                acc.Site = this.SITE_DEFAULT_VALUE;
            } catch(Exception e) {
                //桁数を超過する文字列をセットした場合などにエラーが発生します
                System.debug('エラーが発生しました。' + e.getMessage());
            }
        }
        /**
         * Database.SaveResultを使って処理したレコード1件ずつチェックし
         * 異常終了（エラー）の場合にはCSVファイルにエラーメッセージを添付しメール通知する
         * **/
        Database.SaveResult [] updResultList = Database.update(accList,false);
        for (Database.SaveResult di : updResultList) {
            //エラーの場合は、レコードにエラーメッセージを設定
            if (!di.isSuccess()) {
                for(Database.Error err : di.getErrors()){
                    System.debug(err.getStatusCode() + ': ' + err.getMessage());
                    System.debug('登録エラー: ' + err.getFields());
                }   
            } else {
                System.debug('正常終了');
            }
        }
    }   
    
    /**
     * バッチ処理の最後に実行する処理を定義
     * バッチが異常終了した場合にもfinishで定義した処理は実行される
     */
    global void finish(Database.BatchableContext BC) {
        // 
        System.debug('finish');
    }
}

開発コンソールでバッチを直接実行する

スケジュールクラス（ScheduledBatchUpdateAccount.cls）

/**
 * プログラム名：ScheduledBatchUpdateAccount
 * 概　　　要　：取引先部門一括更新バッチのスケジューラ
 * 作　成　日　：2022/07.01
 * 作　成　者　：cclt(David)
 * 変更履歴　　：
 */
global class ScheduledBatchUpdateAccount implements Schedulable {
    global void execute(SchedulableContext sc) {
        //取引先部門一括更新バッチクラスをインスタンス化
        BatchApexUpdateAccount b = new BatchApexUpdateAccount(); 
        //execcuteBatchでバッチ処理を実行
        Database.executeBatch(b);
    }
}

Schedulableとすることで、以下の画面からスケジュールジョブとして設定することができるようになります。

登録するとスケジュール済みジョブの画面にて、次回の実行予定を確認することができます。

sch（スケジュール）に設定する内容については、

‘Seconds（秒） Minutes（分） Hours（時間） Day_of_month（日） Month（月）Day_of_week（曜日）‘の順

設定方法に関する説明は以下の通り

【特殊なスケジュール設定方法】

・Special Charactersの文字列を使うことで、複雑なスケジュールの指定が可能となります。

①カンマ’,’を使った場合、月のパラメータに”JAN,FEB,MAR”といったように複数の月を指定することができます。

②半角ハイフン’-‘を使うと、月のパラメータの場合、”JAN-MAR”といったように月のFROM-TO指定が可能となります。

※そのほかの例は、以下公式HELPサイトよりご確認ください。

「https://developer.salesforce.com/docs/atlas.en-us.apexcode.meta/apexcode/apex_scheduler.htm」

Batch Apexテストクラス（）

@isTest
private class ScheduledBatchUpdateAccountTest {

    public static String CRON_EXP = '0 0 * * * ? 2022';
    static testmethod void testScheduledJob() {
        // 処理対象の取引先データを作成
        List<Account> accRecs = new List<Account>();
        for (Integer i=0; i<10; i++) {
            Account acc = new Account(
                Name = 'テスト取引先 ' + i,
                Site =  null);
            accRecs.add(acc);
        }
        insert accRecs;
        
        // インサート後のレコードIDとレコードをマップに格納（検証用）
        Map<Id, Account> accMap = new Map<Id, Account>(accRecs);

        // テスト開始
        Test.startTest();
            // スケジュールジョブ実行
            String jobId = System.schedule('ScheduledBatchUpdateAccountTest',
                CRON_EXP, new ScheduledBatchUpdateAccount());
                
        //テスト終了
        Test.stopTest();

        //テスト結果の検証
        for(Account acc:[SELECT Id,Name,Site FROM Account
                        WHERE Id IN :accMap.keyset()]){
            System.assertEquals(acc.Site , null);
        }
    }
}

サンプルコード一覧へ戻る場合は、こちらへ

参考

サンプルコード（テンプレート）Apex/Lwc/Visualforce/Flow

Salesforceの開発を行うときにベースとなるサンプルコードを探すことが多い…

続きを読む

主に以下のような用途で利用いただけます。

・ポータルサイトを使って、お客様からのお問い合わせの管理を行ったり、お客様に向けてナレッジなどの情報を提供する

【必要なライセンス】

カスタマー取引先ポータル（カスタマーポータル）を利用するためには、カスタマーポータルユーザライセンス（※１）が必要となります。

※Experience Cloudユーザライセンス（外部ユーザラインセンスとして、Customer Community、Customer Community Plusのいずれか）

代理店などの自社パートナーに対しては、別のパートナーコミュニティラインセンス（Partner Community）が用意されているので注意

サポーターさん

Developer Edition環境を使えば動作検証は可能です

Developer Edition（無料の開発環境）を持っていない方は、以下の記事を参考にSalesforce組織を取得してください。

参考

セールスフォースの基礎Ⅰ（３）Developer組織の作成～ログインまで

【第三回】セールスフォースの基礎講義 前回の記事では、インスタンスとリージョンの…

続きを読む

カスタマーポータルユーザの作成（ApexTriggerサンプルコード）

ポータルユーザ作成処理

/**
 *　クラス名：CreateCommunityUser 
 *　処理概要：
 *　作成者：CreativeContentLabTokyo
 *　作成日：2022/06/10 
 * 　
*/
global class CreateCommunityUser{

    //カスタムExceptionの定義
    public class CustomException extends Exception {}
    
    /** 
     *　メソッド名：createCommunityUserByContactId
     *　処理概要：取引先責任者のIDを使って、コミュニティユーザを作成
     *　引数：取引先責任者ID
     *　戻り値：ユーザレコード
    **/
    WebService static User createCommunityUserByContactId(String contactId) {
    
      //取引先責任者のIDを使って、氏名とメールアドレスの情報を取得
      Contact contactRec = [SELECT FirstName,LastName,Email,AccountId 
                        FROM Contact WHERE Id =: contactId LIMIT 1];
                           
      //カスタマーコミュニティユーザのプロファイル名を指定してプロファイルIDを取得
      //Profile prof = [SELECT Id,Name FROM profile WHERE name='Customer Community User' LIMIT 1];
      //標準のCustomer Community Userの利用は推奨されないため、コピーしてカスタムプロファイルを生成しておく
      Profile prof = [SELECT Id,Name FROM profile WHERE 
                     name='Custom Customer Community User' LIMIT 1];
      
      //ユーザ名生成
      String strUserName = contactRec.Email + 'ccltPortail';

      //ニックネーム生成
      String strNikcname;
      if(contactRec.FirstName == null){
          strNikcname = contactRec.LastName + Math.random();
      } else {
          strNikcname = contactRec.FirstName + Math.random();
      }
      
      //Alias生成(姓名の文字列短い場合を考慮してパディングしておく)
      String strAlias = String.valueOf(contactRec.LastName.substring(0,1) 
                  + Math.random() ).leftPad(3,'0').substring(0,5);
      
      //カスタマーコミュニティユーザを作成 
      User newCommunityUser = new User(contactId = contactId, 
                          username = strUserName, 
                          firstname = contactRec.FirstName,
                          lastname = contactRec.LastName, 
                          email=contactRec.Email,
                          communityNickname = strNikcname,
                          alias = strAlias, 
                          profileid = prof.Id, 
                          emailencodingkey='ISO-2022-JP',
                          languagelocalekey='ja', 
                          localesidkey='ja_JP', 
                          timezonesidkey='Asia/Tokyo');                  

    try {
          insert newCommunityUser ;
          
    //例外発生時処理
    } catch(DMLException ex) {
        //その他例外処理
        Throw new CustomException('[Exception]'+ex.getMessage());
    }
    //正常終了の場合、作成したユーザレコードを返却
      return newCommunityUser ;

    }
}

テストクラス（CreateCommunityUserTest.cls）

/**--------------------------------------------------------------------------
 * プログラム名:CreateCommunityUserTest
 * 概　要 ：CreateCommunityUserテストクラス 
 * 作成日 ：2022.06.10
 * 作成者 ：cclt
 * --------------------------------------------------------------------------**/
@isTest(SeeAllData=false)
private class CreateCommunityUserTest {

    // テストデータのセットアップ
    @testSetup
    static void initTest(){ 
        // 取引先の作成
        Account acc = new Account(Name='クリエイティブコンテンツラボトウキョウ');
        insert acc;
        // 取引先に紐づく取引先責任者を作成
        contact con = new Contact();
        con.FirstName ='David';
        con.LastName ='cclt';
        con.AccountId = acc.Id;
        con.Email='cclt.customerportaltest@gmail.com';
        insert con;
    }

    @isTest static void Test_Case_createCommunityUser() {   

        //取引先責任者IDを取得
        Contact con = [select id,FirstName,LastName,AccountId,Email 
                        From Contact limit 1];
        User portalUser;
        //テスト開始
        Test.startTest();
            //カスタマーコミュニティユーザ作成処理実行
            portalUser = CreateCommunityUser.createCommunityUserByContactId(con.Id);
        
            //テスト終了
        Test.stopTest();

        //検証
        System.assert(portalUser != null);
        System.assert(portalUser.Email.equals(con.Email));
        
    }   

    @isTest static void Test_Case_ContactNameNull() {   

        // 不正な取引先責任者を作成
        contact con = new Contact();
        con.FirstName ='';
        con.LastName ='cclt';
        insert con;
        User portalUser;
        //テスト開始
        Test.startTest();
            try {
                //カスタマーコミュニティユーザ作成処理実行
                portalUser = CreateCommunityUser.createCommunityUserByContactId(con.Id);             
            } catch (Exception ex) {
                //検証
                System.assert(ex.getMessage().contains('FIELD_INTEGRITY_EXCEPTION'));
            }
            //テスト終了
        Test.stopTest();
        
    }   
}

サンプルコード一覧へ戻る場合は、こちらへ

参考

サンプルコード（テンプレート）Apex/Lwc/Visualforce/Flow

Salesforceの開発を行うときにベースとなるサンプルコードを探すことが多い…

続きを読む

テストクラスの標準テンプレート

テストクラスの標準テンプレート（サンプル）

/**--------------------------------------------------------------------------
* プログラム名 ：TestClassSample
* 概　要       ：xxxのテストクラス
* 作成日       ：yyyy.mm.dd
* 作成者       ：cclt
*--------------------------------------------------------------------------**/
@isTest(SeeAllData=false)
private class TestClassSample {
    
    static final String DEFAULT_STRING = 'テスト内固定文字列の定義';

    //testSetupアノテーションを使ってテストデータを生成
    @testSetup
    static void initTest(){
        TestDataFactory.createTestUsers('標準ユーザ');    
    }
    
    //テストメソッド
    //命名ルール（テストクラスのメソッド名_テストケースNO＿処理期待値）
    static void testClassMethodXX_TestCase1_GetUserInfo(){ 

        //テスト準備
        User runUser = TestDataFactory.createTestUsers('標準ユーザ'); 
    
        //テスト開始
        Test.startTest();
         
        //テスト実行ユーザを指定して実行する場合
        System.runAs(runUser){
            //test code
        }
         
        //テスト終了
        Test.stopTest();
         
        //テスト結果検証
        System.assert(true);
        System.assertEquals('xx' , 'xx');
    }
}

テストデータ作成のユーティリティクラス（TestDataFactory.cls）サンプル

テストで利用するユーザを作成する場合には、ユーザ名の命名に注意する必要があります。ご存じの通りSalesforceのユーザ名は全世界で一意の値とする必要があり、テストクラスでユーザを作成する場合も同様です。

毎回テストクラスを作成するたびに一意のユーザ名を命名するのは大変なので、ユーザ名を検証するようなプログラムでない限りは、ランダムに採番した値を利用する共通のテストクラスを用意しておくと便利です。

以下は、指定プロファイルのユーザを生成するメソッドを含むテストユーティリティクラスとなります。

@isTest(SeeAllData=false)
public with sharing class TestDataFactory  {

    static final String DEFAULT_USER_PROFILE_NAME = '標準ユーザ';
    static final String DEFAULT_USER_DOMAIN_NAME = '@xxxtestorg.com';

    //プロファイル名を指定してランダムなユーザ名のUserレコードを作成
    public static User createTestUsers(String profileName) {    
    
    //ユーザプロファイル取得
    Profile profile = getProfile(profileName); 

    //AESキーを16進にして先頭8桁をuidとして定義
    Blob b = Crypto.GenerateAESKey(128);
    String hex = EncodingUtil.ConvertTohex(b);
    String uid = hex.SubString(0,8);

    User user = new User();
    user.Alias = uid;
    user.Email= uid + DEFAULT_USER_DOMAIN_NAME; 
    user.EmailEncodingKey='UTF-8';
    user.LastName=uid;
    user.LanguageLocaleKey='ja';
    user.LocaleSidKey='ja_JP';
    user.ProfileId = profile.Id;
    user.TimeZoneSidKey='Asia/Tokyo';
    user.UserName= uid + DEFAULT_USER_DOMAIN_NAME; 
    insert user;
    return user;
    }

    //プロファイルが未指定の場合デフォルトのプロファイルをセット
    public static Profile getProfile(String profileName){
        if( String.isBlank(profileName) ){
             profileName = DEFAULT_USER_PROFILE_NAME;
        }
        Profile profile = new Profile();
        profile = [ SELECT Id, Name FROM Profile WHERE Name = :profileName LIMIT 1];
        return profile;
    }
}

実行結果

以下のような簡単なテストクラスを作成して、testSetupからテスト用のユーザを作成した結果のデバッグログです。

@isTest
private class MyTestClass {
    @testSetup
    static void initTest(){
        TestDataFactory.createTestUsers(null);
    }
}

以下、デバッグログ

テストデータ作成時の注意事項

テストデータとして利用できる組織データ

デフォルトでは、Apex テストメソッド (API バージョン 24.0 以降) は、標準オブジェクト、カスタムオブジェクト、カスタム設定データなどの既存の組織データにはアクセスできません。アクセスできるのは、テストメソッドが作成したデータのみです。ただし、組織またはメタデータオブジェクトの管理に使用する次のようなオブジェクトなどは、そのままテストでアクセスできます。

以下については、テストデータを作成しなくてもテスト実行組織に登録されているデータを参照して利用することができます。

• User
• Profile
• Organization
• CronTrigger
• RecordType
• ApexClass
• ApexTrigger
• ApexComponent
• ApexPage

ただし組織のデータを利用するとテスト実行時の状況によってテスト結果に影響を及ぼしてしまうため、可能な限りテストデータはテストクラス、メソッド毎に用意することが推奨されています。

テストクラスで利用可能な＠アノテーション

テストクラスで利用可能なアノテーションについて説明します。

@testSetup

テスト設定メソッドであるtestSetupアノテーションを利用したメソッドは、テストの最初に実行されます。注意事項は以下の通り。

テスト設定メソッドで作成されたレコードは、テストクラス内のすべてのテストメソッドで使用でき、テストクラス実行終了時にロールバックされます。レコード項目の更新やレコード削除など、テストメソッドがこれらのレコードを変更した場合、その変更は、各テストメソッドの実行終了後にロールバックされます。次に実行されるテストメソッドは、元の変更されていない状態のレコードにアクセスできます。

テスト設定メソッドは、テストクラスのデフォルトのデータ分離モードでのみサポートされます。テストクラスまたはテストメソッドが @isTest(SeeAllData=true) アノテーションを使用することで組織データにアクセスできる場合、そのクラスではテスト設定メソッドはサポートされません。テストのためのデータ分離を使用できるのは API バージョン 24.0 以降であるため、テスト設定メソッドを使用できるのもこれらのバージョンのみです。

出典：Salesforce公式Apex開発者ガイド「TestSetup アノテーション」より

【構文例】

@isTest
private class MyTestClass {
    @testSetup
    static void initTest(){
        TestDataFactory.createTestUsers(null);
    }
}

@TestVisible

TestVisibleアノテーションを使用すると、テストクラスでないクラスのprivae非公開メンバーまたは保護メンバーにテストメソッドからアクセスすることができるようになります。注意事項は以下の通り。

【構文例】

@isTest
public class TestVisibleMethodSample {
    // 非公開のメンバー変数
    @TestVisible private static String prefix = 'Prefix';

    // 非公開のメソッド
    @TestVisible 
    private static void updateAccount(String name) {
        //処理コード
    }
}

（テストクラスからの呼び出し）

@isTest
private class TestVisibleMethodTest {
    @isTest static void case_doUpdateAccount_fail() {

        // TestVisibleアノテーションのメンバーにアクセスする
        String prefix = TestVisibleMethodSample.prefix;
        System.assertEquals('Prefix', prefix);

        // TestVisibleアノテーションのメソッドにアクセスする
        TestVisibleMethodSample.updateAccount(prefix);
    }
}

テスト関連トピック

指定ユーザでテストを実行する

System.runAs(uid)メソッドを利用することで、uidで指定されてユーザの権限でテストを実行することが可能。詳細は以下参照。

//テスト実行ユーザを指定して実行する場合　※uidにユーザのIDを指定
System.runAs(uid){
   //test code
}

取引先（Account）のトリガクラス、ハンドラクラス、テストクラスの基本セット

取引先トリガ（AccountTrigger.cls）

Trigger AccountTrigger on Account (before insert, after insert, before update, after update,before delete, after delete, after undelete) {

    //Handlerクラス 
    AccountTriggerHandler handler = new AccountTriggerHandler();

    //レコードが新規登録された時
    if (Trigger.isInsert) {
        if (Trigger.isBefore) {
            // before insertの処理
            handler.onBeforeInsert(Trigger.New);
        } else if (Trigger.isAfter) {
            // after insertの処理
            handler.onAfterInsert(Trigger.New);
        }
    //レコードが更新された時
    } else if (Trigger.isUpdate) {
        if (Trigger.isBefore) {
            // before updateの処理
            handler.onBeforeUpdate(Trigger.Old, Trigger.New);
        } else if (Trigger.isAfter) {
            // after updateの処理
            handler.onAfterUpdate(Trigger.Old, Trigger.New);
        }
    //レコードが削除された時
    } else if (Trigger.isDelete) {
        if (Trigger.isBefore) {
            // before deleteの処理
            handler.onBeforeDelete(Trigger.OldMap, Trigger.NewMap);
        } else if (Trigger.isAfter) {
            // after deleteの処理
            handler.onAfterDelete(Trigger.OldMap, Trigger.NewMap);
        }
    //レコードがごみ箱から復元された時
    } else if (Trigger.isUndelete) {
        if (Trigger.isAfter) {
            // after undeleteの処理
            handler.onAfterUnDelete(Trigger.New);
        }
    }
}

トリガハンドラ（AccountTriggerHandler.cls）

/**--------------------------------------------------------------------------
* プログラム名 ：AccountTriggerHandler
* 概　要       ：Accountトリガーのハンドラークラス
* 作成日       ：yyyy.mm.dd
* 作成者       ：cclt
*--------------------------------------------------------------------------**/
public without sharing class AccountTriggerHandler { 

    /** * before insert */ 
    public void onBeforeInsert(List<Account> newAccList){ 
        for( Account acc : newAccList) {         
            //処理
        } 
    } 
    
    /** * after insert */ 
    public void onAfterInsert(List<Account> newAccList){ 
        for( Account acc : newAccList) {         
            //処理
        } 
    } 
    
    /** * before update */ 
    public void onBeforeUpdate(List<Account> oldAccList,List<Account> newAccList){  
        for( Account acc : newAccList) { 
            //処理
        } 
    } 
    
    /** * after update */ 
    public void onAfterUpdate(List<Account> oldAccList,List<Account> newAccList){  
        for( Account acc : newAccList) { 
            //処理
        } 
    } 
    
    /** * before delete */ 
    public void onBeforeDelete(Map<Id,Account> oldAccMap,Map<Id,Account> newAccMap){  
        for( Account acc : oldAccMap.values()) { 
            //処理
        } 
    } 
    
    /** * after delete */ 
    public void onAfterDelete(Map<Id,Account> oldAccMap,Map<Id,Account> newAccMap){  
        for( Account acc : oldAccMap.values()) { 
            //処理
        } 
    }     
    
    /** * after undelete */ 
    public void onAfterUnDelete(List<Account> newAccList){  
        for( Account acc : newAccList) { 
            //処理
        } 
    }    
}

取引先トリガテストクラス（TestAccountTrigger.cls）

/**--------------------------------------------------------------------------
* プログラム名 ：TestAccountTrigger
* 概　要       ：Accountトリガーのテストクラス
* 作成日       ：yyyy.mm.dd
* 作成者       ：cclt
*--------------------------------------------------------------------------**/
@isTest(SeeAllData=false)
private class TestAccountTrigger {
    
    //テスト設定メソッド
    @testSetup
    static void initTest(){
        // テストデータのセットアップ
        // 取引先の作成後、取引先に紐づく、責任者と商談を作成
        Account acc = new Account(Name='クリエイティブコンテンツラボトウキョウ');
        insert acc;
        
        // 取引先に紐づく取引先責任者を作成
        contact con = new Contact(FirstName='デイビッド',LastName='cclt');
        insert con;
        
        // 取引先に紐づく商談を作成
        List<Opportunity> oppList = new List<Opportunity>();
        oppList.add(new Opportunity(Name=acc.Name + '様との新規商談について',
                                    StageName='Prospecting',CloseDate=System.today().addMonths(1), AccountId=acc.Id));
        oppList.add(new Opportunity(Name=acc.Name + '様との別商談について',
                                    StageName='Prospecting',CloseDate=System.today().addMonths(3),AccountId=acc.Id));
        insert oppList; 
    }
    
    // テストケース：取引先名が更新されたときに商談の名前が更新されるか
    @isTest static void testUpdateAccountName() {      
        
        // 取引先の名前を更新するため最新のレコードを取得
         List<Account> updAccList = [select id, Name from Account];
        updAccList[0].Name = 'CreativeContentLabTokyo';        
        
        // テスト実行
        Test.startTest();

        //トリガー起動のための処理を記述
        Database.SaveResult result = Database.update(updAccList[0], false);

        Test.stopTest();

        // テスト結果の検証 
        System.assert(result.isSuccess());
        System.assert(result.getErrors().size() == 0);

    }
    
    // テストケース：取引先を削除
    @isTest static void testDeleteAccountRecord() {      
        
        // 取引先の名前を更新するため最新のレコードを取得
        List<Account> delAccList = [select id, Name from Account];
        
        // テスト実行
        Test.startTest();

        //トリガー起動のための処理を記述
        delete delAccList[0];

        Test.stopTest();
        
        List<Account> resultAcc = [select id, Name from Account];

        // テスト結果の検証 
        System.assert(resultAcc.isEmpty());

    }   
}

サンプルコード一覧へ戻る場合は、こちらへ

参考

サンプルコード（テンプレート）Apex/Lwc/Visualforce/Flow

Salesforceの開発を行うときにベースとなるサンプルコードを探すことが多い…

続きを読む